1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
; Copyright 1996 Acorn Computers Ltd
;
; Licensed under the Apache License, Version 2.0 (the "License");
; you may not use this file except in compliance with the License.
; You may obtain a copy of the License at
;
; http://www.apache.org/licenses/LICENSE-2.0
;
; Unless required by applicable law or agreed to in writing, software
; distributed under the License is distributed on an "AS IS" BASIS,
; WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
; See the License for the specific language governing permissions and
; limitations under the License.
;
TTL => Convrsions : varicose number->string routines
despatchConvert ROUT
MOV r12, #0 ; All conversions want initial cnt = 0
CMP R11, #OS_ConvertFixedNetStation
BGE EconetStation
Push "R1, lr"
SUB R10, R11, #OS_ConvertHex1 + 1
BIC R10, R10, #3
ADD PC, PC, R10
B Hex_Output ; one digit : -4
B Hex_Output ; 2,3,4,8 digits: 0
B Cardinal_Output ; 4
B Signed_Output ; 8
B Binary_Output ; 12
B Cardinal_Spaced_Output ; 16
B Signed_Spaced_Output ; 20
Hex_Output ROUT
SUBS R11, R11, #OS_ConvertHex1
MOVNE R11, R11, LSL #3
MOVEQ R11, #4
MOV R0, R0, ROR R11
01 MOV R0, R0, ROR #28
AND R10, R0, #&F
CMP R10, #10
ADDGE R10, R10, #"A"-10
ADDLT R10, R10, #"0"
BL addconvchar
BVS naffconversion
SUBS R11, R11, #4
BNE %BT01
endconversion
MOVVC R10, #0
BLVC addconvchar
BVS naffconversion
Pull "R0, lr"
SUB R2, R2, R12
ADD R2, R2, #1 ; null not really a char.
SUB R1, R1, #1
ExitSWIHandler
naffconversion
ADRL R0, ErrorBlock_BuffOverflow
naffconversion_ErrorSet
[ International
BL TranslateError
]
Pull "R1, lr"
B SLVK_SetV
Binary_Output ROUT
SUB R11, R11, #OS_ConvertBinary1-1
MOV R11, R11, LSL #3
MOV R0, R0, ROR R11
01 MOV R0, R0, ROR #31
AND R10, R0, #1
ADD R10, R10, #"0"
BL addconvchar
BVS naffconversion
SUBS R11, R11, #1
BNE %BT01
B endconversion
; cardinal output very similar to BinaryToDecimal
Cardinal_Output ROUT
SUB R11, R11, #OS_ConvertCardinal1-1
MOV R11, R11, LSL #3
MOV R10, #-1
MOV R10, R10, LSL R11
BIC R0, R0, R10
Push "R3-R5"
ADRL R3, TenTimesTable
MOV R5, #9 ; max entry
MOV R4, #0 ; non-0 had flag
02 LDR R11, [R3, R5, LSL #2]
MOV R10, #"0"-1 ; digit value
03 SUBS R0, R0, R11
ADD R10, R10, #1
BCS %BT03
ADD R0, R0, R11
CMP R10, #"0"
CMPEQ R4, #0
BNE %FT04 ; put digit
05 SUBS R5, R5, #1
BPL %BT02 ; next digit
CMP R4, #0
BEQ %FT04 ; R5 must be 0
Pull "R3-R5"
B endconversion
04 MOV R4, #-1
BL addconvchar
BVC %BT05
Pull "R3-R5"
B naffconversion
Signed_Output ROUT
SUB R11, R11, #OS_ConvertInteger1-1
MOV R11, R11, LSL #3
AND R11, R11, #31
RSB R11, R11, #32
AND R11, R11, #31
MOV R0, R0, LSL R11
MOV R0, R0, ASR R11
MOV R12, R2
SWI XOS_BinaryToDecimal
MOVVS r2, r12
ADDVC R1, R1, R2
Swap R2, R12, VC
B endconversion
Cardinal_Spaced_Output ROUT
Signed_Spaced_Output
Push "R1, R2"
; copy our code into the stack (!!)
ADR R1, code_segment
LDMIA R1, {R1, R2, R12}
ADD R2, R2, R11
Pull "R10, R11"
Push "R1, R2, R12"
SUB sp, sp, #12 ; get 12 byte buffer
MOV R1, sp
MOV R2, #12
MOV lr, pc
ADD pc, sp, #12 ; oh for an "execute" instruction!
; note can't get VSet back from this "SWI"
RSB R0, R2, #12 ; bytes got
MOV R1, R10
MOV R2, R11
MOV R12, #0
MOV R11, sp
01 LDRB R10, [R11], #1
BL addconvchar
BVS space_conv_exit
SUBS R0, R0, #1
BEQ space_conv_exit
CMP R10, #"-"
BEQ %BT01
CMP R0, #3
CMPNE R0, #6
CMPNE R0, #9
BNE %BT01
MOV R10, #" "
BL addconvchar
BVC %BT01
space_conv_exit
ADD sp, sp, #12+12
B endconversion
code_segment
Push "lr"
SWI XOS_ConvertCardinal1 - OS_ConvertSpacedCardinal1
Pull "PC"
; +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
; R1 current buffer pos
; R12 character count, R2 character limit
; R10 character
addconvchar ROUT
CMP R2, R12
ORRLES pc, lr, #V_bit
ADD R12, R12, #1
STRB R10, [R1], #1
BICS pc, lr, #V_bit
; +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
; EcoNet conversions
EconetStation ROUT
CMP R11, #OS_ConvertFixedFileSize
BGE FileSizeConversion
Push "R1, lr"
Push "R0"
LDR R0, [R0, #4]
CMP R0, #256
BHS invalidnetworknumber
MOV R10, #" "
BL doabyte
BVS %FT01
CMP R10, #"0"
MOVEQ R10, #"."
CMPNE R11, #OS_ConvertFixedNetStation
BLEQ addconvchar
CMP R10, #"."
MOVEQ R10, #"0"
01
Pull "R0"
BVS naffconversion
LDR R0, [R0]
CMP R0, #0
CMPNE R0, #256
BHS invalidstationnumber
BL doabyte
B endconversion
invalidnetworknumber
INC sp, 4 ; Pull "R0"
ADR R0, ErrorBlock_BadNetwork
B naffconversion_ErrorSet
invalidstationnumber
ADR R0, ErrorBlock_BadStation
B naffconversion_ErrorSet
ErrorBlock_BadNetwork
DCD ErrorNumber_BadNetwork
DCB "BadNet" ; The token for the Global message
DCB 0
ALIGN
ErrorBlock_BadStation
DCD ErrorNumber_BadStation
DCB "BadStn" ; The token for the Global message
DCB 0
ALIGN
doabyte ROUT
; R0 is byte, R11 SWI number (to indicate pad or not)
; return VS for oflo
Push "lr"
CMP R11, #OS_ConvertNetStation
BEQ %FT03
CMP R0, #100
BGE %FT03
BL addconvchar
Pull "PC", VS
02 CMP R0, #10
BGE %FT03
BL addconvchar
Pull "PC", VS
03 CMP R0, #0
BNE %FT01
CMP R11, #OS_ConvertNetStation
Pull "PC", EQ
Pull "lr"
B addconvchar
01 MOV R10, R2
SUB R2, R2, R12 ; bytes left
SWI XOS_BinaryToDecimal
ADD R12, R12, R2
ADD R1, R1, R2
MOV R2, R10
MOV R10, #"0"
Pull "PC"
; +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
; Do length as xxxx bytes or xxxx Kbytes or xxxx Mbytes
; In r0 = size in bytes
; r1 -> buffer
; r2 = buffer length
; r12 = 0
; Out r0 = r1in
; r1 -> terminating zero
; r2 = amount of buffer left
FileSizeConversion ROUT
Push "r1, lr"
Push "r4-r7"
SUB sp, sp, #16 ; May need temp frame
MOV r4, #0 ; No char by default
CMP r0, #4096 ; Only go to 'K' format if > 4K
MOVCS r4, #"K" ; Kilo
MOVCSS r0, r0, LSR #10 ; /1024
ADC r0, r0, #0 ; Round up iff divided and bit fell out
CMP r0, #4096 ; Only go to 'M' format if > 4M
MOVCS r4, #"M" ; Mega
MOVCSS r0, r0, LSR #10 ; /1024 again
ADC r0, r0, #0 ; Round up iff divided and bit fell out
; No need to go to 'G' format as 2^32 = 4096M!
MOV r5, r0 ; Remember for prettiness
CMP r11, #OS_ConvertFixedFileSize
BNE %FT50
Push "r1, r2" ; Remembering state
ADD r1, sp, #4*2 ; Point to our temp buffer
MOV r2, #16
SWI XOS_BinaryToDecimal ; This will not give error
MOV r7, r2 ; Number of chars to do
RSBS r6, r2, #4 ; Number of spaces needed
Pull "r1, r2"
BLE %FT39
30 MOV r10, #" "
BL addconvchar
BVS %FA95
SUBS r6, r6, #1
BNE %BT30
39 MOV r6, sp ; Stick string in punter's buffer
40 LDRB r10, [r6], #1
BL addconvchar
BVS %FA95
SUBS r7, r7, #1
BNE %BT40
B %FT60
50 MOV r12, r2 ; No padding on LHS, easy case
SWI XOS_BinaryToDecimal
MOVVS r2, r12
ADDVC r1, r1, r2
Swap r2, r12, VC
60 MOVVC r10, #" "
BLVC addconvchar
BVS %FA95
MOVS r10, r4 ; Char to print ? VClear
BNE %FT70
CMP r11, #OS_ConvertFixedFileSize ; VClear
BNE %FT75
MOV r10, #" " ; Need to pad in middle
70 BL addconvchar
75 MOVVC r10, #"b" ; 'byte'
BLVC addconvchar
MOVVC r10, #"y"
BLVC addconvchar
MOVVC r10, #"t"
BLVC addconvchar
MOVVC r10, #"e"
BLVC addconvchar
BVS %FA95
CMP r5, #1 ; Prettify (unpluralisationism). VClear
MOVNE r10, #"s"
BNE %FT90
CMP r11, #OS_ConvertFixedFileSize ; VClear
BNE %FA95
MOV r10, #" " ; Need to pad to right
90 BL addconvchar
95 ADD sp, sp, #16
Pull "r4-r7"
B endconversion
; +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
END