; Copyright 1996 Acorn Computers Ltd
;
; Licensed under the Apache License, Version 2.0 (the "License");
; you may not use this file except in compliance with the License.
; You may obtain a copy of the License at
;
; http://www.apache.org/licenses/LICENSE-2.0
;
; Unless required by applicable law or agreed to in writing, software
; distributed under the License is distributed on an "AS IS" BASIS,
; WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
; See the License for the specific language governing permissions and
; limitations under the License.
;
; > $.Source.PMF.Mouse
; Mouse driving code
; Author: Steve Cormie
; Started: 24-Feb-93
; Change history:
;
; Date Who Description
; ---- --- -----------
; 24-Feb-93 SMC Created.
; *****************************************************************************
;
; Mouse initialisation
;
MouseInit
Push "lr"
LDR r11, =ZeroPage+KeyWorkSpace
[ :LNOT: AssemblingArthur
MOV r0, #MouseV
ADRL r1, ReadMouse
SWI OS_Claim
]
MOV r0, #MouseStepCMOS ; setup mouse multipliers from CMOS
BL Read
MOV r0, r0, LSL #24 ; sign extend it
MOVS r0, r0, ASR #24
MOVEQ r0, #1 ; if would be zero, set to 1
STR r0, MouseXMult
STR r0, MouseYMult
MOV r0, #0
STRB r0, MouseButtons
[ STB
STRB r0, MousePresent
]
MOV r0, #MouseCMOS
BL Read
STRB r0, MouseType
Pull "pc"
; *****************************************************************************
;
; MouseButtonChange - Called by keyboard handler when mouse button change
;
; in: R0 = state of buttons (bit0=R, bit1=C, bit2=L)
; R11 -> KeyWorkSpace
;
MouseButtonChange ROUT
Push "R0-R5, R12, R14"
VDWS WsPtr
STRB R0, MouseButtons ; save it for ReadMouse calls
MOV R3, R0
LDR R1, MouseX
LDR R0, [WsPtr, #OrgX]
SUB R1, R1, R0 ; mouse X
LDR R2, MouseY
LDR R0, [WsPtr, #OrgY]
SUB R2, R2, R0 ; mouse Y
[ AssemblingArthur :LOR: Module
LDR R4, =ZeroPage
LDR R4, [R4, #MetroGnome] ; use monotonic variable now
|
BYTEWS WsPtr
LDR R4, RealTime ; doesn't exist in my world
]
MOV R0, #Event_Mouse
BL OSEVEN
MOV WsPtr, #IOC
[ :LNOT:MouseBufferManager
[ MouseBufferFix
LDR R0, MouseX
|
MOV R5, R2 ; save mouse Y
MOV R0, R1
]
BL MouseInsert ; send mouse X low
BCS %FT10 ; buffer full, so don't send rest
MOV R0, R0, LSR #8 ; send mouse X high
BL MouseInsert
[ MouseBufferFix
LDR R0, MouseY
|
MOV R0, R5
]
BL MouseInsert ; send mouse Y low
MOV R0, R0, LSR #8 ; send mouse Y high
BL MouseInsert
MOV R0, R3
BL MouseInsert ; send buttons
MOV R0, R4
BL MouseInsert ; send realtime(0)
MOV R0, R4, LSR #8
BL MouseInsert ; send realtime(1)
MOV R0, R4, LSR #16
BL MouseInsert ; send realtime(2)
MOV R0, R4, LSR #24
BL MouseInsert ; send realtime(3)
|
; Use buffer manager's 'block insert' function
[ {TRUE}
; TMD 26-Feb-93: Fix bug - if X is negative, Y would be inserted in the buffer as -1
LDR R0, MouseX ; 16 bits, sign-extended to 32 bits
MOV R0, R0, LSL #16
LDR R1, MouseY ; ditto
MOV R1, R1, LSL #16
ORR R0, R1, R0, LSR #16 ; combine, having knocked off the troublesome bits
|
LDR R0, MouseX ; 16 bits
LDR R1, MouseY ; 16 bits
ORR R0, R0, R1, LSL #16 ; R0 = Combined 16bit X/Y mouse position
]
ORR R1, R3, R4, LSL #8 ; R1 = Combined 8bit buttons and 24 LSB's of time
MOV R2, R4, LSR #24 ; R2 = MSB of time
SUB SP, SP, #3*4 ; Create local mouse data buffer
STMIA SP, {R0,R1,R2} ; Write mouse data to buffer
MOV R3, #9 ; Mouse packet size
MOV R2, SP ; R2-> block to insert
MOV R1, #(Buff_Mouse:OR:(1:SHL:31)) ; Block insert to mouse buffer
Push "R10,R12"
MOV R10, #INSV ; Insert
BL GoVec2 ; Call the vector in R10
Pull "R10,R12"
ADD SP, SP, #3*4 ; Destroy mouse data buffer
]
10
Pull "R0-R5, R12, PC"
[ :LNOT:MouseBufferManager
MouseInsert
Push "R10,R12,R14"
MOV R10, #INSV
MOV R1, #Buff_Mouse
B GoVec
]
; *****************************************************************************
;
; Read mouse position
;
ReadMouse ROUT
Push "R4-R6,R10-R12"
LDR R11, =ZeroPage+KeyWorkSpace
[ :LNOT:MouseBufferManager
MOV R1, #Buff_Mouse
BL KeyREMOVE
BCS %FT10 ; MouseAhead buffer empty
MOV R4, R2, LSL #16 ; Mouse X Low
BL KeyREMOVE
ORR R4, R4, R2, LSL #24 ; R4 := Mouse X << 16
BL KeyREMOVE
MOV R5, R2, LSL #16 ; Mouse Y Low
BL KeyREMOVE
ORR R5, R5, R2, LSL #24 ; R5 := Mouse Y << 16
BL KeyREMOVE
MOV R6, R2 ; Button state
BL KeyREMOVE ; get realtime
MOV R3, R2
BL KeyREMOVE
ORR R3, R3, R2, LSL #8
BL KeyREMOVE
ORR R3, R3, R2, LSL #16
BL KeyREMOVE
ORR R3, R3, R2, LSL #24
MOV R0, R4, ASR #16 ; sign extend mouse coords
MOV R1, R5, ASR #16
MOV R2, R6
|
SUB SP, SP, #3*4 ; Create 9 byte local mouse data buffer
MOV R3, #9 ; Mouse packet size
MOV R2, SP ; R2-> buffer for data
MOV R1, #(Buff_Mouse:OR:(1:SHL:31)) ; Block remove from mouse buffer
CLRV ; Remove not examine
Push "R10,R12"
MOV R10, #REMV
BL GoVec2 ; Call the vector in R10
Pull "R10,R12"
LDMCCIA SP, {R4,R5,R6}
ADD SP, SP, #3*4 ; Destroy mouse data buffer
BCS %FT10 ; Jump if no buffered data
MOV R0, R4, LSL #16
MOV R0, R0, ASR #16 ; R0 = sign extended x coord
MOV R1, R4, ASR #16 ; R1 = sign extended y coord
AND R2, R5, #&FF ; R2 = button state
MOV R3, R5, LSR #8 ; R3 = 3 low order bytes of time
ORR R3, R3, R6, LSL #24 ; R3 = time
]
; code inserted here 12-Aug-88 to force position read from buffer to be inside
; CURRENT bounding box; this removes the need to flush buffer when changing
; the bounding box.
ADR R4, MouseBounds
LDMIA R4, {R4-R6,R10} ; R4=LCol; R5=BRow; R6=RCol; R10=TRow;
CMP R0, R4
MOVLT R0, R4
CMP R0, R6
MOVGT R0, R6
CMP R1, R5
MOVLT R1, R5
CMP R1, R10
MOVGT R1, R10
[ MouseBufferFix
B %FT20 ; correct for origin after clipping
|
Pull "R4-R6,R10-R12,PC"
]
10
LDRB R2, MouseButtons
[ AssemblingArthur :LOR: Module
LDR R3, =ZeroPage
LDR R3, [R3, #MetroGnome] ; use monotonic variable now
|
BYTEWS WsPtr
LDR R3, RealTime ; doesn't exist in my world
]
LDR R0, MouseX
LDR R1, MouseY
20
VDWS WsPtr
LDR R4, [WsPtr, #OrgX]
SUB R0, R0, R4
LDR R4, [WsPtr, #OrgY]
SUB R1, R1, R4
Pull "R4-R6,R10-R12,PC"
Abso DCB "Abso"
; *****************************************************************************
;
; ProcessMouseXY - Called to update mouse position.
;
; in: r2 = signed 32-bit X movement
; r3 = signed 32-bit Y movement
; r4 = "Abso" if absolute movement
; r11 ->KeyWorkSpace
; out: r2,r3 corrupted
;
ProcessMouseXY
Push "r4,lr"
; check for absolute position
LDR lr, Abso
TEQ r4, lr
BEQ %FT40
; process X movement
CMP r2, #0
BEQ %FT10
MOV r2, r2, LSL #16 ; move delta X to top 16 bits
LDR r4, MouseXMult
MUL r2, r4, r2
LDR r4, MouseX
ADD r2, r2, r4, LSL #16 ; add signed value in top 16 bits
MOV r2, r2, ASR #16 ; sign extend to 32 bits
LDR r4, MouseBoundLCol ; bound to bounding box
CMP r2, r4
MOVLT r2, r4
LDR r4, MouseBoundRCol
CMP r4, r2
MOVLT r2, r4
STR r2, MouseX
10
; process Y movement
CMP r3, #0
Pull "r4,pc",EQ
MOV r3, r3, LSL #16 ; move delta Y to top 16 bits
LDR r4, MouseYMult
MUL r3, r4, r3
LDR r4, MouseY
ADD r3, r3, r4, LSL #16 ; add signed value in top 16 bits
MOV r3, r3, ASR #16 ; sign extend to 32 bits
LDR r4, MouseBoundBRow ; bound to bounding box
CMP r3, r4
MOVLT r3, r4
LDR r4, MouseBoundTRow
CMP r4, r3
MOVLT r3, r4
STR r3, MouseY
Pull "r4,pc"
40
; process absolute position
MOV r2, r2, ASL #16 ; look only at bottom 16 bits,
MOV r3, r3, ASL #16 ; sign extended
MOV r2, r2, ASR #16
MOV r3, r3, ASR #16
LDR r4, MouseBoundLCol ; bound to bounding box
CMP r2, r4
MOVLT r2, r4
LDR r4, MouseBoundRCol
CMP r4, r2
MOVLT r2, r4
STR r2, MouseX
LDR r4, MouseBoundBRow ; bound to bounding box
CMP r3, r4
MOVLT r3, r4
LDR r4, MouseBoundTRow
CMP r4, r3
MOVLT r3, r4
STR r3, MouseY
Pull "r4,pc"
[ AssemblePointerV
; *****************************************************************************
;
; PollPointer - Called on VSync to get mouse changes.
;
; out: corrupts r0-r3,r9-r11
;
PollPointer
Push "r4,r12,lr"
LDR r11, =ZeroPage+KeyWorkSpace
LDRB r0, MouseReporting
TEQ r0, #0
Pull "r4,r12,pc",NE
MOV r0, #0 ; Request pointer state.
LDRB r1, MouseType
MOV r2, #0 ; Default to no movement.
MOV r3, #0
MOV r4, #0 ; They might fill this in
SavePSR r9 ; Save current PSR.
WritePSRc SVC_mode+I_bit, r10 ; Call PointerV in SVC mode, no IRQs.
MOV r10, #PointerV ; Call PointerV to get movements & button states
Push "lr" ; Save SVC lr.
BL CallVector
Pull "lr" ; Restore SVC lr.
RestPSR r9
[ STB
TEQ r2, #0
TEQEQ r3, #0
MOVNE lr, #1
STRNEB lr, MousePresent
BLNE ProcessMouseXY
|
BL ProcessMouseXY
]
Pull "r4,r12,pc"
; *****************************************************************************
;
; PointerVector - the default PointerV claimant
;
PointerVector
CMP r0, #PointerReason_Report
Pull pc, NE
Push "r2,r3,r11"
LDR r11, =ZeroPage+KeyWorkSpace
LDRB lr, MouseType
TEQ r1, lr
MOVEQ lr, #1
STREQB lr, MouseReporting
[ STB
TEQ r2, #0
TEQEQ r3, #0
MOVNE lr, #1
STRNEB lr, MousePresent
BLNE ProcessMouseXY
|
BL ProcessMouseXY
]
Pull "r2,r3,r11,pc"
; *****************************************************************************
;
; PointerSWI - Handle SWI OS_Pointer calls (read/set pointer type).
;
PointerSWI
LDR r11, =ZeroPage+KeyWorkSpace
TEQ r0, #0
LDREQB r0, MouseType
BEQ SLVK
[ STB
TEQ r0, #2
LDREQB r0, MousePresent
BEQ SLVK
]
TEQ r0, #1
BNE %FT10
Push "r0,r10,r12,lr"
STRB r1, MouseType
MOV r0, #0
STRB r0, MouseReporting
MOV r0, #2
MOV r10, #PointerV
BL CallVector
Pull "r0,r10,r12,lr"
B SLVK
10
ADRL r0, ErrorBlock_BadParameters
[ International
BL TranslateError
]
B SLVK_SetV
]
END